@Echo off
cd /D "%~dp0"
set "Params=%1"
Echo. > DriverSod.ini
If "%Params%"=="" set "Params=/?"
If "%Params%"=="/?" Goto :Help
If "%Params%"=="/all" set "ins=$" && set "ext=cab" && set "pat=Y:\" && set "Action=Searching and Installing All Missing" && goto all
If "%Params%"=="/inst" set "ins=$" && set "ext=cab" && set "pat=Y:\" && set "Action=Searching and Installing Selected"
If "%Params%"=="/copy" set "ins=" && set "ext=cab" && set "pat=Y:\" && set "Action=Searching and Copying Missing"
If "%Params%"=="/infi" set "ins=$" && set "ext=inf" && set "pat=%Windir%\inf\" && set "Action=Installing Copied"
If "%2"=="" Goto :Help

:Loop
Shift
If "%~1" Equ "" goto :Run
Echo DEVI %ins%%pat%%1.%ext% >> DriverSod.ini && Goto :Loop
Goto :eof

:all
for /f %%f in ('dir /b "%pat%*.%ext%"') do Echo DEVI %ins%%pat%%%f >> DriverSod.ini

:Run
Echo.
Echo %Action% Drivers. Please Wait...
Pecmd.exe load %Windir%\System32\DriverSod.ini
Goto :eof

:Help
Cls
Echo.
Echo Drivers Must be Packed in Top Folders in Cab files in the Root of USB Drive.
Echo Any Number of Driver Packs will be Parsed in given order.
Echo.
Echo Ex:
Echo.
Echo DriverSod /all
Echo     Will Install all Devices found in All cab Files in Alphabetic Order.
Echo.
Echo DriverSod /inst Chips Stor Usb Lan Wifi
Echo     Will Install all Devices found in Specified cab Files.
Echo.
Echo DriverSod /copy Chips Wifi video
Echo     Will Only Copy Found Devices in Cabs and no Installation is Done.
Echo.
Echo DriverSod /infi IntelHDA
Echo     Will Install the specified inf File. Drivers needs to be copied First.
Echo.
Echo All /action must be in lowercase
Echo All Paths and Files Extentions are Automatically Assumed.
Echo.
Pause